控制LCD更新时间

• 概述

• 在HT Basic中的样本程序

概述

本部分提供通过控制LCD显示器的更新时间，提高命令处理时间的样本程序。

• 将通道/迹线的最大数量设置为9通道/9迹线时，此样本程序正常运行。

此程序设置必需的测量条件，然后关闭LCD显示器的更新。其次，它执行测量、读取结果并立即更新屏幕。此程序重复执行这个测量程序10次。

有关程序的详情，请参见改善命令处理速度。

在HT Basic中的样本程序（cont_upd.htb）

10 REAL Trace1(1:201,1:2),Trace2(1:201,1:2)

20 DIM Buff$[9],Img$[30]

30 INTEGER Nop,I

40 !

50 ASSIGN @Agte507x TO 717

60 ASSIGN @Binary TO 717;FORMAT OFF

70 !

80 OUTPUT @Agte507x;":SENS1:SWE:TYPE LIN"

90 OUTPUT @Agte507x;":SENS1:FREQ:CENT 950E6"

100 OUTPUT @Agte507x;":SENS1:FREQ:SPAN 100E6"

110 OUTPUT @Agte507x;":SENS1:SWE:POIN 201"

120 OUTPUT @Agte507x;":TRIG:SOUR BUS"

130 OUTPUT @Agte507x;":INIT1:CONT ON"

140 FOR I=2 TO 9

150 OUTPUT @Agte507x;":INIT"&VAL$(I)&":CONT OFF"

160 NEXT I

170 !

180 OUTPUT @Agte507x;":DISP:SPL D1"

190 OUTPUT @Agte507x;":DISP:WIND1:SPL D1_2"

200 !

210 OUTPUT @Agte507x;":CALC1:PAR:COUN 2"

220 OUTPUT @Agte507x;":CALC1:PAR1:DEF S21"

230 OUTPUT @Agte507x;":CALC1:PAR1:SEL"

240 OUTPUT @Agte507x;":CALC1:FORM MLOG"

250 OUTPUT @Agte507x;":CALC1:PAR2:DEF S11"

260 OUTPUT @Agte507x;":CALC1:PAR2:SEL"

270 OUTPUT @Agte507x;":CALC1:FORM MLOG"

280 !

290 OUTPUT @Agte507x;":DISP:ENAB OFF"

300 OUTPUT @Agte507x;":FORM:DATA REAL"

310 !

320 FOR I=1 TO 10

330 OUTPUT @Agte507x;":TRIG:SING"

340 OUTPUT @Agte507x;"*OPC?"

350 ENTER @Agte507x;Buff$

360 !

370 ! Read Trace Data

380 !

390 OUTPUT @Agte507x;":CALC1:PAR1:SEL"

400 OUTPUT @Agte507x;":CALC1:DATA:FDAT?"

410 ENTER @Agte507x USING "#,8A";Buff$

420 ENTER @Binary;Trace1(*)

430 ENTER @Agte507x USING "#,1A";Buff$

440 !

450 OUTPUT @Agte507x;":CALC1:PAR2:SEL"

460 OUTPUT @Agte507x;":CALC1:DATA:FDAT?"

470 ENTER @Agte507x USING "#,8A";Buff$

480 ENTER @Binary;Trace2(*)

490 ENTER @Agte507x USING "#,1A";Buff$

500 !

510 ! Update Display

520 !

530 OUTPUT @Agte507x;":DISP:UPD"

540 NEXT I

550 END

说明

50行到60行

为I/O通道分配GPIB地址。

80行到110行

这些行为线性扫描设置扫描类型，并将扫描中心值设置为950 MHz、扫宽值设置为100 MHz、测量点数设置为201。

120行到160行

这些行将触发源设置为总线触发，打开通道1的连续活动模式，然后关闭通道2到通道9的连续活动模式。

180行到190行

这些行只显示通道1的窗口，并水平排列两个图表。

210行到270行

这些行分别将通道1的迹线数设置为2，迹线1的测量参数及其数据格式设置为S21和Log Mag，迹线2的分别设置为S11和Log Mag。

290行

这行关闭LCD屏幕更新。

300行

这行将数据传输格式设置为二进制。

320行到540行

这些行重复以下程序十次。

340行到360行：这些行对仪器进行触发，等待测量周期的完成。

400行到440行：读出通道1中迹线1的格式化数组。

460行到500行：读出通道1中迹线2的格式化数组。

540行：这行更新LCD屏幕一次。